home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
TPUG - Toronto PET Users Group
/
TPUG Users Group CD
/
TPUG Users Group CD.iso
/
CRS
/
crs04.d81
/
dcmr.sfx
/
cnv.disk file4.7
(
.txt
)
next >
Wrap
Commodore BASIC
|
1990-02-12
|
1KB
|
41 lines
100 FORI=1TO60:SP$=SP$+" ":NEXT:N2=0:PN=0
110 DIM PN$(1500)
120 POKE53280,14:POKE53281,15:PRINT"[147][151]":OPEN15,8,15:GOTO1000
200 INPUT#15,EN,EM$,ET,ES
210 IFEN=0THENRETURN
220 PRINT"ERROR # ";EN;EM$;ET;ES
230 PRINT#15,"I":RETURN
1000 PRINT"[147] DISK CATALOG MANAGER/REPORTER[146]"
1010 PRINT"CONVERSION PROGRAM TO CONVERT"
1020 PRINT" 'DISK FILE 4.7.C' FILES."
1030 PRINT"INSERT DISKETTE TO READ FROM AND"
1040 PRINT" ENTER 'DISK FILE 4.7.C' FILE NAME"
1045 PRINT" OR END"
1050 INPUTN$:IFN$="END"THEN1170
1060 OPEN8,8,8,N$+",S,R":GOSUB200:IFEN<>0THENCLOSE8:GOTO1030
1070 INPUT#8,N1
1090 PRINT"TOTAL PROGRAMS[146] ";N1
1100 PRINT"IS THIS THE FILE YOU WANT (Y/N) ";
1110 X$="":INPUTX$:IFX$="N"THENCLOSE8:GOTO1030
1120 IFX$<>"Y"THEN1100
1150 FORI=1TON1
1154 N2=N2+1:IFPN<1500THENPN=PN+1:INPUT#8,PN$(PN)
1155 NEXT
1160 CLOSE8:PRINT:IFPN<N2THENPRINT"";N2-PN;" ENTRIES OVER 1500 IGNORED!"
1165 GOTO1030
1170 NN=PEEK(45)+256*PEEK(46)-096
1180 SYSNN,PN,PN$(1)
1300 PRINT"NOW, INSERT DISKETTE TO RECEIVE"
1310 PRINT"CONVERTED FILE AND ENTER SAVE"
1320 PRINT"FILE NAME ";:INPUTN$
1330 OPEN8,8,8,N$+",P,W":GOSUB200:IFEN<>0THENCLOSE8:GOTO1300
1340 PRINT#8,CHR$(224);CHR$(15);:D$=LEFT$(SP$,18):T$=LEFT$(SP$,60)
1350 PRINT#8,D$;T$;CHR$(0);CHR$(0);"N";
1360 FORI=1TO7:PRINT#8,CHR$(0);:NEXT
1400 PRINT"TOTAL TO WRITE IS ";PN
1410 FORI=1TOPN:PRINT#8,LEFT$(PN$(I),16);RIGHT$(PN$(I),4);
1430 CT=CT+1:IFCT=100THENCT=0:C1=C1+100:PRINT"PROGRESS COUNT IS ";C1
1440 NEXT
1450 CLOSE8:CLOSE15
1460 PRINT"...FINISHED":END